DESCRIPTION = "sysmocom OsmoBTS"
LICENSE = "AGPLv3"
LIC_FILES_CHKSUM="file://COPYING;md5=73f1eb20517c55bf9493b7dd6e480788"

SRC_URI = "git://git.osmocom.org/osmo-bts.git;protocol=git;branch=master;name=osmobts;destsuffix=git \
           git://git.osmocom.org/openbsc;protocol=git;branch=master;name=openbsc;destsuffix=openbsc"
SRCREV_osmobts = "f7fd2e47986d5385de5e892037a9bd3b663c1085"
SRCREV_openbsc = "46cb8514a5a60459214ddee776b37a422abb625e"
PV = "0.0+git${SRCPV}"
PR = "r14"
S = "${WORKDIR}/git"

SRCREV_FORMAT = "openbsc-rosmobts"
DEPENDS = "libosmocore libosmo-abis femtobts-api"

EXTRA_OECONF += "--enable-sysmocom-bts"

inherit autotools update-rc.d

# Select the API version
inherit femtobts_api
CPPFLAGS += " ${BTS_HW_VERSION} "

do_configure_prepend() {
	ln -sf ../openbsc openbsc
}

do_install_append() {
	install -d ${D}${sysconfdir}/osmocom
	install -m 0660 ${S}/doc/examples/osmo-bts.cfg ${D}${sysconfdir}/osmocom
	install -m 0755 ${S}/contrib/respawn.sh ${D}${sysconfdir}/osmocom/
	install -m 0644 ${S}/contrib/screenrc-sysmobts ${D}${sysconfdir}/osmocom/
	install -d ${D}${sysconfdir}/init.d
	install -m 0755 ${S}/contrib/sysmobts.init ${D}${sysconfdir}/init.d/sysmobts
}

CONFFILES_${PN} = "${sysconfdir}/osmocom/osmo-bts.cfg"
INITSCRIPT_PACKAGES = "${PN}"
INITSCRIPT_NAME_${PN} = "sysmobts"
INITSCRIPT_PARAMS_${PN} = "defaults 30 30"

PACKAGES =+ "osmo-bts-remote"

FILES_osmo-bts-remote = " ${bindir}/sysmobts-remote "