DESCRIPTION = "sysmocom OsmoBTS"
LICENSE = "AGPLv3"
LIC_FILES_CHKSUM="file://COPYING;md5=73f1eb20517c55bf9493b7dd6e480788"

SRC_URI = "git://git.osmocom.org/osmo-bts.git;protocol=git;branch=sysmocom/0.3.5-stable;name=osmobts;destsuffix=git \
           git://git.osmocom.org/openbsc;protocol=git;branch=master;name=openbsc;destsuffix=openbsc \
           file://gcc6-linking-fix.patch"
SRCREV_osmobts = "a4bd813081e788012c72f34d31150cdf02db307f"
SRCREV_openbsc = "57ee78078905c7499bd4e6857f8981d22badfcac"
PV = "0.4.3+git${SRCPV}"
PR = "r20.${META_TELEPHONY_OSMO_INC}"
S = "${WORKDIR}/git"

SRCREV_FORMAT = "openbsc-rosmobts"

DEPENDS = "libosmocore libosmo-abis femtobts-api gpsd"
DEPENDS_append_sysmobts-v2 = " femtobts-api"
DEPENDS_append_sysmobts2100 = " lc15-firmware"

RDEPENDS_${PN} += "coreutils"

RDEPENDS_${PN}_append_sysmobts-v2 = " sysmobts-firmware (>= 5.1)"
RCONFLICTS_${PN}_append_sysmobts-v2 = " sysmobts-firmware (< 5.1)"

RDEPENDS_${PN}_append_sysmobts2100 = " lc15-firmware"

EXTRA_OECONF_sysmobts-v2 += "--enable-sysmocom-bts"
EXTRA_OECONF_sysmobts2100 += "--enable-litecell15"

inherit autotools pkgconfig


# Select the API version
inherit femtobts_api
CPPFLAGS_append_sysmobts-v2 = " ${BTS_HW_VERSION} "

do_configure_prepend() {
	ln -sf ../openbsc openbsc || true
}

do_compile_append_sysmobts-v2() {
	cd ${S}/contrib/sysmobts-calib/
	oe_runmake
}

do_install_append() {
	install -d ${D}${sysconfdir}/osmocom

	# Future sysmobts-mgr handling
	install -d ${D}${systemd_unitdir}/system/multi-user.target.wants/
	install -m 0644 ${S}/contrib/sysmobts-mgr.service ${D}${systemd_unitdir}/system/
	ln -sf ../sysmobts-mgr.service ${D}${systemd_unitdir}/system/multi-user.target.wants/
}

do_install_append_sysmobts-v2() {
	install -m 0755 ${S}/contrib/sysmobts-calib/sysmobts-calib ${D}${bindir}/

	install -m 0660 ${S}/doc/examples/osmo-bts.cfg ${D}${sysconfdir}/osmocom

	# Install systemd and enable on sysinit
	install -d ${D}${systemd_unitdir}/system/multi-user.target.wants/
	install -m 0660 ${S}/doc/examples/sysmo/sysmobts-mgr.cfg ${D}${sysconfdir}/osmocom
	install -m 0644 ${S}/contrib/sysmobts.service ${D}${systemd_unitdir}/system/
	ln -sf ../sysmobts.service ${D}${systemd_unitdir}/system/multi-user.target.wants/
}

do_install_append_sysmobts2100() {
	install -m 0660 ${S}/doc/examples/litecell15/osmo-bts.cfg ${D}${sysconfdir}/osmocom

	# ensure consistent naming
	mv ${D}/${bindir}/lc15bts-util ${D}/${bindir}/sysmobts-util
	mv ${D}/${bindir}/lc15bts-mgr ${D}/${bindir}/sysmobts-mgr

	# Install systemd and enable on sysinit
	install -d ${D}${systemd_unitdir}/system/multi-user.target.wants/
	install -m 0660 ${S}/doc/examples/litecell15/lc15bts-mgr.cfg ${D}${sysconfdir}/osmocom/
	install -m 0644 ${S}/contrib/osmo-bts-lc15.service ${D}${systemd_unitdir}/system/
	ln -sf ../osmo-bts-lc15.service ${D}${systemd_unitdir}/system/multi-user.target.wants/
}


CONFFILES_${PN} = "${sysconfdir}/osmocom/osmo-bts.cfg"
CONFFILES_${PN}_append_sysmobts-v2 = " ${sysconfdir}/osmocom/sysmobts-mgr.cfg"

# somehow it seems not posible to use _append constructs on PACKAGES
#PACKAGES_append_sysmobts-v2 = " osmo-bts-remote sysmobts-calib sysmobts-util"
PACKAGES =+ "osmo-bts-remote sysmobts-calib sysmobts-util"

FILES_${PN} += "${systemd_unitdir}"
FILES_osmo-bts-remote_sysmobts-v2 = " ${bindir}/osmo-bts-sysmo-remote "
FILES_sysmobts-calib_sysmobts-v2 = " ${bindir}/sysmobts-calib "
FILES_sysmobts-util = " ${bindir}/sysmobts-util "