Add kernel for LogicPD OMAP3430 Zoom Kit

git-svn-id: https://svn.o-hand.com/repos/poky/trunk@4558 311d38ba-8fff-0310-9ca6-ca027cbcb966

meta/packages/linux/linux-omap-zoom_2.6.22.19.bb

@@ -0,0 +1,11 @@
+require linux-omap.inc
+
+COMPATIBLE_MACHINE = "omap-zoom"
+
+PR = "r0"
+FILESDIR = "${WORKDIR}"
+
+SRC_URI = "http://www.omapzoom.org/pub/kernel/linux-ldp-v1.2.tar.gz \
+           file://defconfig-omap-zoom"
+
+S = "${WORKDIR}/linux-ldp-v1.2"

meta/packages/linux/linux-omap.inc

@@ -0,0 +1,42 @@
+SECTION = "kernel"
+DESCRIPTION = "Linux kernel for TI OMAP devices"
+LICENSE = "GPL"
+
+KERNEL_OUTPUT = "arch/${ARCH}/boot/compressed/${KERNEL_IMAGETYPE}"
+
+inherit kernel
+
+COMPATIBLE_MACHINE = "omap-zoom"
+
+do_configure_prepend() {
+
+	rm -f ${S}/.config || true
+
+        if [ "${TARGET_OS}" = "linux-gnueabi" -o  "${TARGET_OS}" = "linux-uclibcgnueabi" ]; then
+                echo "CONFIG_AEABI=y"                   >> ${S}/.config
+                echo "CONFIG_OABI_COMPAT=y"             >> ${S}/.config
+        else
+                echo "# CONFIG_AEABI is not set"        >> ${S}/.config
+                echo "# CONFIG_OABI_COMPAT is not set"  >> ${S}/.config
+        fi
+
+        sed     -e '/CONFIG_AEABI/d' \
+                -e '/CONFIG_OABI_COMPAT=/d' \
+                '${WORKDIR}/defconfig-${MACHINE}' >>'${S}/.config'
+
+        yes '' | oe_runmake oldconfig
+
+}
+
+do_deploy() {
+	install -d ${DEPLOY_DIR_IMAGE}
+	install -m 0644 arch/${ARCH}/boot/${KERNEL_IMAGETYPE} ${DEPLOY_DIR_IMAGE}/${KERNEL_IMAGETYPE}-${PV}-${MACHINE}-${DATETIME}.bin
+	cd ${DEPLOY_DIR_IMAGE}
+	ln -sf ${KERNEL_IMAGETYPE}-${PV}-${MACHINE}-${DATETIME}.bin ${KERNEL_IMAGETYPE}-${MACHINE}.bin
+	tar -cvzf ${DEPLOY_DIR_IMAGE}/modules-${KERNEL_RELEASE}-${MACHINE}.tgz -C ${D} lib
+}
+
+do_deploy[dirs] = "${S}"
+
+addtask deploy before do_populate_staging after do_install
+